E000R
LOMEM=2048
HIMEM=4096
10 DIM A$(13),B$(4),C$(20),D$(20):A$="A23456789TJQK":B$="CDHS":N=52:S=0
15 DIM A(52):FOR I=1 TO 52:A(I)=I-1:NEXT I
20 INPUT "WELCOME TO 21.  YOUR NAME",C$:PRINT "OK, HERE WE GO ";C$;"."
30 P=0:D=P:A1=P:A2=P:GOSUB 3000:IF B THEN 35:PRINT "END--STOPPED AT 30":END 
35 PRINT "I SHOW  ";:GOSUB 2020:E=J:F=K:PRINT:PRINT "YOU HAVE  ";:GOSUB 2040:GOSUB 2040:IF P<21 THEN 45
37 PRINT "BLACKJACK!!":B=B+B/2:GOTO 300
40 PRINT "PLEASE ANSWER 'YES' OR 'NO'. ";
45 IF P#11 THEN 50:INPUT "DO YOU WISH TO DOUBLE DOWN",D$:IF D$="N" OR D$="NO" THEN 50:IF D$#"Y" AND D$#"YES" THEN 44:B=B+B
46 GOSUB 2040:GOTO 60
50 INPUT "HIT",D$:IF D$="N" OR D$="NO" THEN 60:IF D$#"Y" AND D$#"YES" THEN 40:TAB 11:GOSUB 2040:IF P<22 THEN 50:PRINT "BUSTED ";:GOTO 200
60 PRINT:PRINT "MY CARDS: ";A$(E,E);B$(F,F);"  ";
70 FOR I=1 TO 600:NEXT I:IF D>17 OR D=17 AND A2=0 THEN 80:GOSUB 2020:GOTO 70
80 IF D>21 THEN 85:IF D>P THEN 200:IF D<P THEN 90:PRINT "DRAW":GOTO 400
85 PRINT "I BUST, ";
90 PRINT "YOU WIN":GOTO 300
200 S=S-B:PRINT "   I WIN":GOTO 210+RND(5)
210 PRINT "YOU'D BETTER TRY HARDER, ";C$;".":GOTO 400
211 PRINT "IF YOU DON'T IMPROVE, ";C$;", I'LL QUIT.":GOTO 400
212 PRINT "YOU COULDN'T BEAT A 5-YEAR-OLD, ";C$;".":GOTO 400
213 PRINT "GETTING TOO OLD, ";C$;"?":GOTO 400
214 PRINT "STICK TO TIC-TAC-TOE, ";C$;".":GOTO 400
300 S=S+B:GOTO 310+RND(3)
310 PRINT "I'LL HAVE TO TRY HARDER":GOTO 400
311 PRINT "I CAN'T BELIEVE YOUR RUN OF LUCK, ";C$:GOTO 400
312 PRINT "NOW I'M GETTING MAD"
400 TAB 20:PRINT "WINNINGS: ";S:PRINT:GOTO 30
1000 N=0:FOR I=1 TO 120:J=RND(52)+1:K=RND(52)+1:L=A(J):A(J)=A(K):A(K)=L:NEXT I:RETURN 
2000 IF N>50 THEN GOSUB 1000:N=N+1:J=A(N)/4+1:K=A(N)MOD 4+1:C=J-J/10*(J-10):PRINT A$(J,J);B$(K,K);"  ";:RETURN 
2020 GOSUB 2000:D=D+C+(C=1)*10:A2=A2+(C=1):IF D<22 OR A2=0 THEN RETURN :A2=A2-1:D=D-10:RETURN 
2040 GOSUB 2000:P=P+C+(C=1)*10:A1=A1+(C=1):IF P<22 OR A1=0 THEN RETURN :A1=A1-1:P=P-10:RETURN 
3000 INPUT "BET",B:IF B<=3000 THEN RETURN :PRINT "LIMIT IS $3000. ";:GOTO 3000
RUN